这个类是用于处理字符串的，是老外写的，我把里面的功能和参数加了说明
使用方法：
=============== test.asp================
<!--#include file="stringoperations.asp"-->
<%
dim str
set str = new stringoperations
test = str.tochararray("check this out")
response.write "<strong>str.tochararray</strong>: "
for i = 0 to ubound(test)
response.write test(i) & " "
next
response.write "<br><br>"
test1 = str.arraytostring(test)
response.write "<strong>str.arraytostring</strong>: " & test1
response.write "<br><br>"
response.write "<strong>str.startswith</strong>: " & str.startswith(test1, "ch")
response.write "<br><br>"
response.write "<strong>str.endwith</strong>: " & str.endswith(test1, "out")
response.write "<br><br>"
response.write "<strong>str.clone</strong>: " & str.clone("abc", 10)
response.write "<br><br>"
response.write "<strong>str.trimstart</strong>: " & str.trimstart(test1, 3)
response.write "<br><br>"
response.write "<strong>str.trimend</strong>: " & str.trimend(test1, 2)
response.write "<br><br>"
response.write "<strong>str.swapcase</strong>: " & str.swapcase("hihihi")
response.write "<br><br>"
response.write "<strong>str.isalphabetic</strong>: " & str.isalphabetic("!")
response.write "<br><br>"
response.write "<strong>str.capitalize</strong>: " & str.capitalize("clara fehler")
set str = nothing
%>
=============== stringoperations.asp================
<%
class stringoperations
'****************************************************************************
'' @功能说明: 把字符串换为char型数组
'' @参数说明: - str [string]: 需要转换的字符串
'' @返回值: - [array] char型数组
'****************************************************************************
public function tochararray(byval str)
redim chararray(len(str))
for i = 1 to len(str)
chararray(i-1) = mid(str,i,1)
next
tochararray = chararray
end function
'****************************************************************************
'' @功能说明: 把一个数组转换成一个字符串
'' @参数说明: - arr [array]: 需要转换的数据
'' @返回值: - [string] 字符串
'****************************************************************************
public function arraytostring(byval arr)
for i = 0 to ubound(arr)
strobj = strobj & arr(i)
next
arraytostring = strobj
end function
'****************************************************************************
'' @功能说明: 检查源字符串str是否以chars开头
'' @参数说明: - str [string]: 源字符串
'' @参数说明: - chars [string]: 比较的字符/字符串
'' @返回值: - [bool]
'****************************************************************************
public function startswith(byval str, chars)
if left(str,len(chars)) = chars then
startswith = true
else
startswith = false
end if
end function
'****************************************************************************
'' @功能说明: 检查源字符串str是否以chars结尾
'' @参数说明: - str [string]: 源字符串
'' @参数说明: - chars [string]: 比较的字符/字符串
'' @返回值: - [bool]
'****************************************************************************
public function endswith(byval str, chars)
if right(str,len(chars)) = chars then
endswith = true
else
endswith = false
end if
end function
'****************************************************************************
'' @功能说明: 复制n个字符串str
'' @参数说明: - str [string]: 源字符串
'' @参数说明: - n [int]: 复制次数
'' @返回值: - [string] 复制后的字符串
'****************************************************************************
public function clone(byval str, n)
for i = 1 to n
value = value & str
next
clone = value
end function
'****************************************************************************
'' @功能说明: 删除源字符串str的前n个字符
'' @参数说明: - str [string]: 源字符串
'' @参数说明: - n [int]: 删除的字符个数
'' @返回值: - [string] 删除后的字符串
'****************************************************************************
public function trimstart(byval str, n)
value = mid(str, n+1)
trimstart = value
end function
'****************************************************************************
'' @功能说明: 删除源字符串str的最后n个字符串
'' @参数说明: - str [string]: 源字符串
'' @参数说明: - n [int]: 删除的字符个数
'' @返回值: - [string] 删除后的字符串
'****************************************************************************
public function trimend(byval str, n)
value = left(str, len(str)-n)
trimend = value
end function
'****************************************************************************
'' @功能说明: 检查字符character是否是英文字符 a-z or a-z
'' @参数说明: - character [char]: 检查的字符
'' @返回值: - [bool] 如果是英文字符,返回true,反之为false
'****************************************************************************
public function isalphabetic(byval character)
asciivalue = cint(asc(character))
if (65 <= asciivalue and asciivalue <= 90) or (97 <= asciivalue and asciivalue <= 122) then
isalphabetic = true
else
isalphabetic = false
end if
end function
'****************************************************************************
'' @功能说明: 对str字符串进行大小写转换
'' @参数说明: - str [string]: 源字符串
'' @返回值: - [string] 转换后的字符串
'****************************************************************************
public function swapcase(str)
for i = 1 to len(str)
current = mid(str, i, 1)
if isalphabetic(current) then
high = asc(ucase(current))
low = asc(lcase(current))
sum = high + low
return = return & chr(sum-asc(current))
else
return = return & current
end if
next
swapcase = return
end function
'****************************************************************************
'' @功能说明: 将源字符串str中每个单词的第一个字母转换成大写
'' @参数说明: - str [string]: 源字符串
'' @返回值: - [string] 转换后的字符串
'****************************************************************************
public function capitalize(str)
words = split(str," ")
for i = 0 to ubound(words)
if not i = 0 then
tmp = " "
end if
tmp = tmp & ucase(left(words(i), 1)) & right(words(i), len(words(i))-1)
words(i) = tmp
next
capitalize = arraytostring(words)
end function
end class
%>
